Como usar a função CONCATENAR no Excel

O Microsoft Excel é uma ferramenta extremamente versátil, que pode ser usada em muitas aplicações diferentes. Quando você pensa no Excel, talvez imagine logo uma planilha cheia de números confusos. Mas o Excel também é útil para trabalhar com texto. A função CONCATENATE do Excel é uma das muitas funções que você pode usar para manipular texto na sua planilha.

O objetivo da função CONCATENATE é bem simples: ela serve para juntar várias cadeias de texto em um único texto. Neste artigo, mostro como usar a CONCATENATE para unir texto na sua planilha no formato que você quiser.

Você também vai encontrar instruções passo a passo, como juntar células com um delimitador, como a CONCATENATE se compara à CONCAT e à TEXTJOIN e como corrigir os erros mais comuns.

Sintaxe

=CONCATENATE(text 1, [text 2], …)

Onde texto 1, texto 2, etc. são os trechos de texto que você quer unir. Podem ser referências a uma célula com texto, um número ou um texto digitado diretamente na fórmula entre aspas.

Como usar a função CONCATENATE

Para mostrar como usar a função CONCATENATE, veja o exemplo abaixo. Quero juntar o nome e o sobrenome em uma única cadeia de texto.

Faço isso na captura de tela abaixo com a fórmula =CONCATENATE(B2," ",A2).

Concatenar no Excel — CONCATENATE junta nomes e sobrenomes com um espaço na coluna Full Name

Observe que adicionei um espaço entre os nomes usando um espaço entre aspas (" "). Sem isso, o nome e o sobrenome ficariam juntos, sem espaço entre eles.

Com o espaço, a função combina três itens de texto diferentes aqui. Liste cada cadeia de texto e separe-as com vírgulas para juntar todas em uma só.

Vou detalhar isso no próximo exemplo. Aqui, além do nome completo, quero escrever a idade de cada pessoa. Para isso, pego os dados da planilha (nome, sobrenome e idade) e digito o restante da frase dentro da fórmula.

Concatenar no Excel — CONCATENATE monta frases como Alex Jones is 20 years old a partir de três colunas

Observe como incluo os espaços no texto que digito na fórmula. Por exemplo, incluí um espaço antes e depois de " is ", para que o espaço apareça quando esse texto for combinado com o que vem antes e depois.

Você também pode adicionar os espaços separadamente (use " " separado por vírgula dentro da fórmula). Mas é mais fácil incluí-los junto com o restante do texto, para reduzir o total de itens que você está combinando. E, se esquecer um espaço em algum lugar (o que acontece o tempo todo!), você vai notar o erro assim que terminar a fórmula e poderá voltar e adicioná-lo facilmente.

CONCATENATE com números

Agora que você já viu como combinar texto de algumas formas diferentes, vou mostrar um exemplo com números.

Quando você inclui um número na função CONCATENATE, não precisa colocá-lo entre aspas: basta separá-lo com uma vírgula, como qualquer outro item da função. Você pode até fazer um cálculo dentro da função. É exatamente isso que faço neste exemplo, multiplicando a idade de cada pessoa por 12 para obter a idade aproximada em meses.

Concatenar no Excel — CONCATENATE multiplica a idade por 12 dentro da fórmula para dar a idade em meses

Observe que não precisei adicionar uma nova coluna aos dados para fazer o cálculo que transforma anos em meses: faço isso direto na fórmula, digitando =CONCATENATE(B9," ",A9,"'s age in months is ", C9*12).

Para juntar colunas inteiras em vez de células isoladas, veja como combinar várias colunas do Excel em uma. O artigo explica a TEXTJOIN e uma fórmula INDEX que empilha colunas.

Juntar texto com o operador &

Use o E comercial (&) em vez da função CONCATENATE para combinar texto rapidamente. Ao colocar um E comercial entre os textos que você quer unir, você diz ao Excel para combiná-los sem precisar digitar a função CONCATENATE.

Faço isso no exemplo abaixo com esta fórmula: =B2 & ” ” & A2.

Concatenar no Excel — o operador e comercial junta nomes e sobrenomes com um espaço

A escolha entre o E comercial e a função CONCATENATE é uma questão de preferência pessoal: os dois funcionam bem para combinar texto, então escolha o que preferir!

CONCATENATE com a função TEXT

Combine a função TEXT com a função CONCATENATE para formatar números no seu texto.

Veja o exemplo abaixo. Uso a função TODAY dentro da função TEXT para indicar o dia do aniversário de cada pessoa (neste exemplo, suponha que todos fazem aniversário no mesmo dia!).

A fórmula que uso aqui é =CONCATENATE(B2," ",A2,"'s birthday is ",TEXT(TODAY(),"DDDD")).

Concatenar no Excel — CONCATENATE com TEXT e TODAY adiciona o dia da semana de cada aniversário

Como concatenar no Excel passo a passo

Estes passos usam a CONCAT, a versão mais recente da CONCATENATE (CONCATENAR). Aqui as duas recebem os mesmos argumentos, então você pode digitar qualquer um dos nomes. Todo texto que você digitar na fórmula, inclusive um delimitador como um espaço, fica entre aspas.

As capturas de tela vêm de um Excel com configurações regionais europeias, por isso mostram ponto e vírgula entre os argumentos. Nas versões do Excel dos EUA e do Reino Unido, você digita vírgulas, como nos passos.

Juntar duas células com um espaço

Siga os passos abaixo para concatenar strings usando um espaço como delimitador.

1. Digite a função CONCAT e selecione a célula com a primeira string.

Concatenar no Excel — CONCAT digitada na coluna fullname com a célula A2 do nome selecionada

2. Adicione uma vírgula e, em seguida, um espaço entre aspas. Adicione outra vírgula e selecione a célula com a segunda string.

Concatenar no Excel — um espaço entre aspas e a célula B2 do sobrenome adicionados à CONCAT

3. Adicione o parêntese de fechamento e pressione Enter para ver o resultado. Clique duas vezes na alça de preenchimento para copiar a fórmula até a última linha. A fórmula final é =CONCAT(A2," ",B2).

Concatenar no Excel — nomes e sobrenomes juntados com um espaço na coluna fullname

Como concatenar células com um espaço, uma vírgula ou um delimitador personalizado

Você pode separar os itens com qualquer caractere ou string. Por exemplo, pode juntar as diferentes linhas de um endereço com uma vírgula e um espaço para obter o endereço completo. Para usar outro delimitador, como um hífen, coloque-o entre as aspas. Para uma quebra de linha, use CHAR(10) (CARACT) sem aspas e ative Quebrar texto automaticamente.

1. Digite a função CONCAT e selecione a célula com a primeira linha do endereço.

Concatenar com um delimitador no Excel — CONCAT iniciada com a rua na coluna full_address

2. Adicione uma vírgula para separar os argumentos e digite o delimitador entre aspas: uma vírgula seguida de um espaço.

Concatenar com um delimitador no Excel — uma vírgula e um espaço entre aspas depois da rua

3. Repita o passo anterior para cada linha do endereço, como mostrado abaixo.

Concatenar com um delimitador no Excel — células de cidade, estado e país adicionadas com uma vírgula e um espaço entre cada uma

4. Adicione o parêntese de fechamento e pressione Enter para ver o resultado. Clique duas vezes na alça de preenchimento para copiar a fórmula para baixo. A fórmula final é =CONCAT(A2,", ",B2,", ",C2,", ",D2), que retorna 8058 Shoshone, Vero Beach, FL, United States.

Juntar células com um delimitador usando TEXTJOIN

A função TEXTJOIN (UNIRTEXTO) é ideal para juntar vários itens com delimitadores, porque poupa muita digitação. Além disso, você pode ignorar as células vazias da seleção com o segundo parâmetro: 'ignore_empty'. Por exemplo, =TEXTJOIN(" ",TRUE,A2:B2) junta o nome e o sobrenome de A2:B2 com um espaço.

TEXTJOIN no Excel — TEXTJOIN com um espaço como delimitador e TRUE junta os nomes e sobrenomes de A2:B2

CONCATENATE vs. CONCAT vs. TEXTJOIN

Embora a função CONCATENATE continue disponível por compatibilidade com versões anteriores do Excel, o site de suporte da Microsoft recomenda usar a substituta: CONCAT. Com a função CONCAT do Excel, você pode juntar qualquer valor digitado ou o conteúdo de células, sejam textos, números ou datas. É possível concatenar até 254 itens ou um total de 32.767 caracteres.

Ao contrário da antecessora, a CONCAT aceita matrizes. Porém, ao contrário da TEXTJOIN, ela não tem um parâmetro 'delimitador', então cada ocorrência precisa ser adicionada separadamente. Ou seja, se você precisa concatenar vários itens com delimitadores, vale a pena usar a TEXTJOIN.

Função	Versões do Excel	Junta um intervalo como A2:C2	Delimitador	Ignora células vazias
CONCATENAR	Todas as versões	Não, é preciso listar cada célula	Digitado entre cada item	Não
CONCAT	Excel 2019 e posteriores, Microsoft 365	Sim	Digitado entre cada item	Não
TEXTJOIN	Excel 2019 e posteriores, Microsoft 365	Sim	Uma vez, como primeiro argumento	Sim, com TRUE como segundo argumento

A CONCATENATE ainda funciona em todas as versões, então as pastas de trabalho antigas continuam calculando. Para fórmulas novas, a CONCAT faz o mesmo e também aceita intervalos, e a TEXTJOIN poupa digitação quando todos os itens usam o mesmo delimitador.

Erros comuns da CONCATENATE e como corrigi-los

As palavras ficam grudadas. A CONCATENATE não adiciona nada entre os itens que junta. Adicione você mesmo o espaço ou o delimitador, entre aspas, como em =CONCATENATE(B2," ",A2).
O Excel diz que há um problema com a fórmula. Verifique o separador entre os argumentos. O Excel usa vírgulas nos EUA e no Reino Unido e ponto e vírgula nas regiões em que a vírgula é o separador decimal.
Erro #NAME? (#NOME?). Texto digitado na fórmula sem aspas, um nome de função escrito errado ou a CONCAT ou a TEXTJOIN em uma versão anterior ao Excel 2019 retornam #NAME?. Adicione as aspas, confira a grafia ou use a CONCATENATE ou o operador &.
Números e datas perdem a formatação. A CONCATENATE junta o valor armazenado, então $3.99 vira 3.99 e a data 3/28/2023 vira 45013. Coloque o valor dentro da TEXT (TEXTO), por exemplo TEXT(B2,”$0.00″) ou TEXT(B2,”mm/dd/yyyy”), como no exemplo da TEXT mais acima.
Um intervalo não é juntado. A CONCATENATE não consegue transformar A2:C2 em uma única string de texto: em vez disso, você recebe valores separados ou um erro. Liste cada célula ou use a CONCAT ou a TEXTJOIN, que aceitam intervalos.
A célula mostra a fórmula, não o resultado. A célula estava formatada como Texto antes de você digitar a fórmula. Mude o formato para Geral e pressione F2 e Enter.

O oposto da CONCATENATE no Excel: TEXTSPLIT

Se você precisar dividir strings em vez de concatená-las, pode usar a função TEXTSPLIT (DIVIDIRTEXTO), disponível no Microsoft 365 e no Excel 2024. Por exemplo, =TEXTSPLIT(A2,", ") divide o endereço completo de volta em rua, cidade, estado e país. Para conhecer outras formas de dividir células no Excel, confira nosso guia sobre como dividir células no Excel.