Una tarea común en Excel a menudo implica tomar un conjunto de datos y hacer un recuento de las ocurrencias que coinciden con ciertas características. El Función CONTAR.SI de Excel te permite hacer precisamente eso: cuenta el número de puntos de datos (celdas) que cumplen un cierto criterio que tú especificas dentro de la función.
Debido al amplio rango de criterios que puedes ingresar, la función CONTAR.SI te permite filtrar tus datos prácticamente de cualquier manera que desees.
Esta guía muestra cómo usar COUNTIF (CONTAR.SI) en Excel con texto, números, referencias de celda, operadores y comodines, con ejemplos paso a paso. También explica COUNTIFS (CONTAR.SI.CONJUNTO), que cuenta las celdas que cumplen varias condiciones a la vez, y los errores con los que es más probable que te encuentres.
COUNTIF o COUNTIFS: ¿cuál necesitas?
Las dos funciones cuentan las celdas que cumplen una condición. La diferencia está en cuántas condiciones comprueban.
- CONTAR.SI comprueba un rango frente a una condición, como el número de vegetarianos de una lista.
- CONTAR.SI.CONJUNTO comprueba uno o varios rangos, cada uno frente a su propia condición, y solo cuenta una fila cuando se cumplen todas las condiciones, como las ventas de productA de 700 $ o más.
Usa COUNTIF para una sola condición y COUNTIFS cuando una fila tiene que cumplir dos o más condiciones a la vez. Para contar las filas que cumplen una condición u otra, como las personas de 20 o 21 años, suma dos resultados de COUNTIF, como en el ejemplo con números de más abajo. COUNTIFS existe en Excel desde Excel 2007.
Sintaxis
- range es el grupo de células que desea contar
- criterios es la característica que decidirá si cada celda se cuenta o no. Puede ser una expresión, un número, una referencia de celda o una cadena de texto.
Cómo usar CONTAR.SI en Excel
Criterios como cadena de texto
Para ilustrar algunas de las formas en que puede usar la función CONTAR.SI en Excel, eche un vistazo al conjunto de datos a continuación. Describe las preferencias dietéticas de un grupo de personas. En el primer ejemplo, utilizo CONTAR.SI para contar el número de vegetarianos en el grupo escribiendo =CONTAR.SI(D2:D9,"Sí").
En este ejemplo, el criterio que he especificado es una cadena de texto. La función examina todas las celdas en el rango que he indicado y devuelve el número de celdas que coinciden con el criterio; en este caso, el número de instancias donde aparece “Sí” en la columna.
Criterios como referencia de celda
Otra forma de indicar el criterio es usar una referencia de celda. Eche un vistazo al siguiente ejemplo. Aquí, cuento el número de personas con alergias usando la celda E4 como mi criterio. Por supuesto, esa celda contiene la cadena de texto “Yes”, por lo que esta es solo una alternativa a escribir "Yes" en la fórmula.
La fórmula que utilizo aquí es =CONTAR.SI(E2:E9;E4).
Criterios como número
También puedes poner un número como criterio en la función CONTAR.SI. En este ejemplo, quiero contar solo personas de cierta edad, así que pongo la edad directamente en la función.
Observe que, a diferencia de una cadena de texto, no necesita poner comillas alrededor de un número en una fórmula.
Otra cosa que he hecho de forma distinta aquí es sumar dos funciones COUNTIF. El motivo es que quiero contar a todas las personas de 20 y 21 años.
Para hacer esto, utilizo dos funciones CONTAR.SI separadas. Esto puede sonar engorroso, pero la buena noticia es que, dado que CONTAR.SI solo proporciona un recuento final de las celdas que cumplen los criterios, puedes usar múltiples funciones CONTAR.SI en la misma fórmula. Simplemente las sumas para obtener el recuento total de todas las celdas que coinciden con múltiples criterios. También puedes restar funciones CONTAR.SI cuando quieras obtener las celdas que se encuentran entre dos criterios.
Sumar resultados de COUNTIF de esta forma te da un recuento de tipo O: personas de 20 o 21 años. Cuando todas las condiciones tienen que cumplirse a la vez, como las personas de 20 años que además son vegetarianas, usa la función CONTAR.SI.CONJUNTO, que verás más adelante en esta guía.
Criterios con operador lógico
Los operadores lógicos como > y < (mayor que y menor que) se pueden usar dentro de tus criterios.
En el ejemplo siguiente, utilizo el símbolo < para contar a todas las personas menores de 23 años en mi conjunto de datos, escribiendo =CONTAR.SI(B2:B9;"<23").
Tenga en cuenta que este criterio incluye tanto el símbolo del operador lógico como un número. El criterio debe ir entre comillas, a diferencia de cuando solo se utiliza un número.
Los siguientes operadores lógicos se pueden utilizar de la misma manera:
Criterios concatenados
Ahora has visto la parte del criterio de la función como una cadena de texto, un número y una referencia de celda.
Déjame mostrarte cómo hacer una combinación de estos concatenando (uniendo) diferentes criterios usando el ampersand (&). Hago esto a continuación escribiendo =CONTAR.SI(B2:B9,"<"&B7).
El resultado de esta función es exactamente el mismo que el del ejemplo anterior.
Excepto que ahora he utilizado el símbolo & para concatenar una referencia de celda (B7) que contiene el número 23, en lugar de escribir simplemente el número 23 en la fórmula.
Comodines
Además de las diferentes maneras de establecer los criterios en la función CONTAR.SI, existe algo más llamado “comodines”.
Los caracteres comodín * y ? se pueden usar dentro de tus criterios para indicar una coincidencia con cualquier carácter (?) o cualquier secuencia de caracteres (*).
El ejemplo de abajo tiene criterios muy específicos. Quiero contar todas las ocurrencias de un nombre de 5 letras que termina en “y”. Para hacer esto, puedes usar el comodín ?.
Este carácter comodín es un marcador de posición para cualquier carácter, por lo que cuando escribo =CONTAR.SI(A2:A9,"????y") Indico que quiero contar todas las instancias donde hay cuatro caracteres (que pueden ser cualquier cosa) seguidos de una “y”.
Usa el segundo comodín (*) cuando la longitud del criterio no importa. Por ejemplo, si no me importara la longitud del nombre, solo que terminara en "y", el criterio podría ser "*y".
Otro uso útil para el comodín * es deshacerse de las celdas en blanco. Lo demuestro en la captura de pantalla a continuación usando la fórmula =CONTAR.SI(A2:A13;"*").
Como el * representa cualquier cantidad de cualquier carácter, ¡las únicas celdas que no cumplen con este criterio son las que no contienen nada!
Criterios y operadores de COUNTIF en Excel
A continuación tienes algunos de los operadores más útiles para tus criterios de COUNTIF, tanto si necesitas contar según texto, números, celdas vacías y no vacías o valores booleanos.
Valores de texto
Para buscar coincidencias con valores de texto tienes muchas opciones. Para una coincidencia exacta, basta con poner la cadena entre comillas o usar la referencia a la celda que la contiene. Para coincidencias parciales, puedes usar los caracteres comodín que verás a continuación.
- * Coincide con 0 o más caracteres.
- ? Coincide con un solo carácter.
- ~ Si necesitas buscar los símbolos "*" o "?", añade la tilde (~) antes del símbolo para escaparlo y que no se use como comodín.
Por último, la función no distingue entre mayúsculas y minúsculas.
Números y fechas
Si quieres usar un valor numérico exacto como criterio, no hace falta ponerlo entre comillas. En cambio, si quieres usar operadores de comparación, tienes que poner el criterio entre comillas.
- <> distinto de
- = igual a
- >= mayor o igual que
- <= menor o igual que
- > mayor que
- < menor que
Las fechas funcionan igual, porque Excel las guarda como números. Por ejemplo, =COUNTIF(B2:B100,">="&DATE(2026,1,1)) cuenta las fechas a partir del 1 de enero de 2026, incluido.
Celdas vacías y no vacías
Usa estos criterios para contar celdas vacías y no vacías.
- "" (dos comillas sin nada entre ellas) cuenta las celdas vacías, como en =COUNTIF(A2:A13,"").
- "<>" cuenta las celdas que no están vacías, como en =COUNTIF(A2:A13,"<>").
El comodín * del ejemplo de comodines también omite las celdas vacías, pero solo cuenta las celdas que contienen texto, así que deja fuera los números.
Valores TRUE y FALSE (VERDADERO y FALSO)
Por último, también puedes usar los valores booleanos TRUE y FALSE para contar celdas según el resultado de una fórmula o para contar casillas de verificación marcadas o sin marcar. Por ejemplo, =COUNTIF(E2:E20,TRUE) cuenta las casillas marcadas en E2:E20.
Ejemplos de COUNTIF en Excel, paso a paso
Ahora que ya has repasado la sintaxis de la función COUNTIF, es hora de ver algunos ejemplos de cómo usarla en distintas situaciones.
Imagina que tienes una tabla de Excel con datos de ventas que incluye el nombre del agente de ventas, su equipo, el producto y el importe de la venta. Necesitas obtener distintos recuentos para tu informe de ventas, pero contar a mano sería una pesadilla, porque la tabla tiene quinientas filas.
Primero, selecciona cada columna y ve a la pestaña 'Fórmulas'. Haz clic en 'Crear desde la selección' para dar nombre a los rangos y trabajar con los datos más fácilmente.
Las capturas de pantalla proceden de un Excel con configuración regional europea, por eso muestran punto y coma entre los argumentos. En las versiones de Excel de EE. UU. y Reino Unido se escriben comas, como en los pasos siguientes.
Contar celdas que contienen un texto exacto
Sigue estos pasos para contar las celdas que contienen un texto concreto. En este caso, vamos a contar el número de ventas de 'Barret Smitten'.
1. Escribe la función COUNTIF y selecciona el rango de celdas que quieres contar. En este caso, usaré el rango con nombre 'sales_agent'.
2. Añade una coma y escribe el criterio entre comillas.
3. Añade el paréntesis de cierre y pulsa 'Intro' para ver el resultado.
La fórmula final es =COUNTIF(sales_agent,"Barret Smitten"), y devuelve 21.
Contar celdas que contienen parte de un texto
En lugar de una coincidencia exacta, puedes usar comodines para buscar parte del texto. Por ejemplo, vamos a contar el número de ventas de 'Northteam' buscando 'North'.
1. Escribe la función COUNTIF y selecciona el rango de celdas que quieres contar.
2. Añade una coma y escribe el criterio entre comillas.
3. Añade el paréntesis de cierre y pulsa 'Intro' para ver el resultado.
La fórmula final es =COUNTIF(sales_team,"North*"), y devuelve 189.
Contar valores mayores o iguales que un número
En este ejemplo, vamos a calcular el número de ventas con un importe mayor o igual que 500 $.
1. Escribe la función COUNTIF y selecciona el rango de celdas que quieres contar.
2. Añade una coma y escribe el criterio entre comillas.
3. Añade el paréntesis de cierre y pulsa 'Intro' para ver el resultado.
La fórmula final es =COUNTIF(sales_amount,">=500"), y devuelve 412.
Cómo usar COUNTIFS en Excel con varios criterios
En Microsoft Excel, puedes usar la función COUNTIFS para contar celdas según varios criterios, y cada criterio se puede aplicar a uno o varios rangos.
Sintaxis de COUNTIFS
=COUNTIFS(rango_criterios1, criterio1, rango_criterios2, criterio2, ...)
Igual que COUNTIF, la función COUNTIFS tiene dos parámetros obligatorios. Sin embargo, puedes añadir parámetros adicionales para comprobar varios rangos con distintos criterios. Recuerda que todos los rangos deben tener las mismas dimensiones, es decir, el mismo número de filas y columnas.
- criteria_range1: el rango de celdas que quieres comprobar con el primer criterio.
- criterion1: la condición o prueba que quieres aplicar al primer rango.
- criteria_range2, criterion2, …: pares opcionales. Añade tantos como necesites. COUNTIFS solo cuenta una fila cuando cumple todos los criterios.
Los ejemplos siguientes usan la misma tabla de ventas que los ejemplos de COUNTIF.
COUNTIFS con dos criterios en un mismo rango
Por ejemplo, vamos a contar las ventas de más de 600 $ y menos de 1000 $. La etiqueta de las capturas de pantalla dice 500 $, pero la fórmula y su resultado usan 600 $.
1. Escribe la función COUNTIFS y selecciona el rango de celdas que quieres contar.
2. Añade una coma y escribe el primer criterio entre comillas.
3. Añade una coma y selecciona el mismo rango que antes. Añade otra coma y escribe el segundo criterio entre comillas.
4. Añade el paréntesis de cierre y pulsa 'Intro' para ver el resultado.
La fórmula final es =COUNTIFS(sales_amount,">600",sales_amount,"<1000"), y devuelve 103.
COUNTIFS con criterios en rangos distintos
Por último, vamos a contar el número de ventas de productA con un importe mayor o igual que 700 $.
1. Escribe la función COUNTIFS y selecciona el primer rango de celdas.
2. Añade una coma y escribe el primer criterio entre comillas.
3. Añade una coma y selecciona el segundo rango de celdas. Añade otra coma y escribe el segundo criterio entre comillas.
4. Añade el paréntesis de cierre y pulsa 'Intro' para ver el resultado.
La fórmula final es =COUNTIFS(product,"productA",sales_amount,">=700"), y devuelve 80.
Errores comunes de COUNTIF y COUNTIFS y cómo corregirlos
- Excel dice que hay un problema con la fórmula. Revisa el separador entre argumentos. Excel usa comas en EE. UU. y Reino Unido, y punto y coma en las regiones donde la coma es el separador decimal. Comprueba también que cada criterio de texto lleva comillas a ambos lados.
- Un operador devuelve un error. El operador va dentro de las comillas junto con el número, como en "<23". Para comparar con una celda, une el operador a la referencia de celda con un ampersand: "<"&B7.
- Un texto que parece igual no se cuenta. Basta un espacio al final para impedir una coincidencia exacta, así que "Barret Smitten " y "Barret Smitten" cuentan como textos distintos. Quita los espacios con TRIM (ESPACIOS) o termina el criterio con el comodín *.
- COUNTIFS devuelve #VALUE! (#¡VALOR!). Todos los rangos de criterios tienen que tener el mismo tamaño. A2:A100 y B2:B90 no coinciden, así que haz que todos los rangos empiecen y terminen en las mismas filas.
- #VALUE! cuando el rango está en otro libro. COUNTIF y COUNTIFS no pueden leer un libro que está cerrado. Ábrelo y la fórmula se vuelve a calcular.
- Resultados incorrectos con textos largos. COUNTIF no puede buscar coincidencias con textos de más de 255 caracteres. Divide el criterio en dos y une las mitades con &, como en "first part"&"second part".
Así se usan COUNTIF y COUNTIFS en Excel
A estas alturas, esperamos que tengas claras las muchas formas de usar las funciones COUNTIF y COUNTIFS de Excel y que puedas ponerlas en práctica con tus propios datos. ¡Feliz recuento!
Para sumar valores en lugar de contarlos, consulta cómo usar SUMIF en Excel. Para buscar un valor en una tabla, lee nuestra guía de VLOOKUP en Excel, y para conocer más fórmulas útiles, consulta las 10 funciones principales de Excel.
Si trabajas en Google Sheets, consulta cómo usar COUNTIFS en Google Sheets y nuestro artículo sobre la fórmula DCOUNT en Google Sheets.
English 
Español 
Português do Brasil 
Français