Como usar a função CONT.SE no Excel

Uma tarefa comum no Excel geralmente envolve a obtenção de um conjunto de dados e a contagem do número de ocorrências que correspondem a determinadas características. As COUNTIF Função do Excel permite fazer exatamente isso: ele conta o número de pontos de dados (células) que atendem a um determinado critério que você especifica na função.

Devido à ampla gama de critérios que podem ser inseridos, a função COUNTIF permite que você filtre seus dados de praticamente qualquer maneira que desejar.

Este guia mostra como usar COUNTIF (CONT.SE) no Excel com texto, números, referências de célula, operadores e curingas, com exemplos passo a passo. Ele também aborda COUNTIFS (CONT.SES), que conta as células que atendem a várias condições ao mesmo tempo, e os erros que você tem mais chance de encontrar.

COUNTIF ou COUNTIFS: qual você precisa usar?

As duas funções contam as células que atendem a uma condição. A diferença está em quantas condições elas verificam.

• CONT.SE verifica um intervalo em relação a uma condição, como o número de vegetarianos em uma lista.
• CONT.SES verifica um ou mais intervalos, cada um em relação à sua própria condição, e só conta uma linha quando todas as condições são atendidas, como as vendas de productA de US$ 700 ou mais.

Use COUNTIF para uma única condição e COUNTIFS quando uma linha precisa atender a duas ou mais condições ao mesmo tempo. Para contar as linhas que atendem a uma condição ou a outra, como pessoas de 20 ou 21 anos, some dois resultados de COUNTIF, como no exemplo com números mais abaixo. O COUNTIFS existe no Excel desde o Excel 2007.

Sintaxe

• range é o grupo de células que você deseja contar
• critérios é a característica que decidirá se cada célula será contada ou não. Pode ser uma expressão, um número, uma referência de célula ou uma cadeia de texto.

Como usar o COUNTIF no Excel

Critérios como string de texto

Para ilustrar algumas das maneiras pelas quais você pode usar a função CONT.SE no Excel, dê uma olhada no conjunto de dados abaixo. Ele descreve as preferências alimentares de um grupo de pessoas. No primeiro exemplo, uso COUNTIF para registrar o número de vegetarianos no grupo digitando =COUNTIF(D2:D9, "Yes").

Neste exemplo, o critério que especifiquei é uma cadeia de texto. A função examina todas as células no intervalo que indiquei e retorna o número de células que correspondem aos critérios - nesse caso, o número de instâncias em que “Yes” aparece na coluna.

Critérios como referência de célula

Outra forma de indicar os critérios é usar uma referência de célula. Dê uma olhada no exemplo abaixo. Aqui, eu conto o número de pessoas com alergias usando a célula E4 como meu critério. É claro que essa célula contém a string de texto Yes, portanto, essa é apenas uma alternativa para digitar “Yes” na fórmula.

A fórmula que uso aqui é =COUNTIF(E2:E9,E4).

Critérios como um número

Você também pode colocar um número como critério na função COUNTIF. Neste exemplo, quero contar apenas pessoas de uma determinada idade, portanto, coloquei a idade diretamente na função.

Observe que, diferentemente de uma cadeia de texto, não é necessário colocar aspas em torno de um número em uma fórmula.

Outra coisa que fiz de forma diferente aqui foi somar duas funções COUNTIF. O motivo é que quero contar todas as pessoas de 20 e 21 anos.

Para isso, utilizo duas funções COUNTIF separadas. Isso pode parecer complicado, mas a boa notícia é que, como a função CONT.SE apenas fornece uma contagem final das células que atendem aos critérios, você pode usar várias funções CONT.SE na mesma fórmula. Basta somá-las para obter a contagem total de todas as células que atendem a vários critérios. Você também pode subtrair funções CONT.SE quando quiser obter células que estejam entre dois critérios.

Somar resultados de COUNTIF dessa forma dá uma contagem do tipo OU: pessoas de 20 ou 21 anos. Quando todas as condições precisam ser verdadeiras ao mesmo tempo, como pessoas de 20 anos que também são vegetarianas, use a função COUNTIFS, explicada mais adiante neste guia.

Critérios com operador lógico

Operadores lógicos como > e < (maior que e menor que) podem ser usados em seus critérios.

No exemplo abaixo, eu uso o símbolo < para contar todas as pessoas com menos de 23 anos em meu conjunto de dados, digitando =COUNTIF(B2:B9,"<23").

Observe que esse critério inclui o símbolo do operador lógico e um número. Os critérios devem ser colocados entre aspas, ao contrário do que ocorre quando você usa apenas um número.

Os operadores lógicos a seguir podem ser usados da mesma forma:

Critérios concatenados

Agora você já viu a parte de critérios da função como uma cadeia de texto, um número e uma referência de célula.

Vou lhe mostrar como fazer uma combinação desses critérios concatenando (combinando) diferentes critérios usando o E comercial (&). Faço isso abaixo digitando =COUNTIF(B2:B9,"<"&B7).

O resultado dessa função é exatamente o mesmo do exemplo anterior.

Exceto pelo fato de que agora usei o símbolo & para concatenar uma referência de célula (B7) que contém o número 23, em vez de simplesmente digitar o número 23 na fórmula.

Curingas

Além das diferentes maneiras de definir os critérios na função COUNTIF, há outra coisa chamada “curingas”.

Os caracteres curinga * e ? podem ser usados em seus critérios para indicar uma correspondência com qualquer caractere (?) ou qualquer sequência de caracteres (*).

O exemplo abaixo tem critérios muito específicos. Quero contar todas as ocorrências de um nome de 5 letras que termina em “y”. Para fazer isso, você pode usar o curinga ?.

Esse caractere curinga é um substituto para qualquer caractere, portanto, quando eu digito =COUNTIF(A2:A9,"????y") Eu indico que quero contar todas as instâncias em que há quatro caracteres (que podem ser qualquer coisa) seguidos por um “y”.

Use o segundo curinga (*) quando o tamanho do critério não importa. Por exemplo, se eu não me importasse com o tamanho do nome, apenas com o fato de terminar em "y", o critério poderia ser "*y".

Outro uso útil do curinga * é eliminar células em branco. Demonstro isso na captura de tela abaixo usando a fórmula =COUNTIF(A2:A13, "*").

Como o * representa qualquer número de caracteres, as únicas células que não atendem a esse critério são aquelas que não contêm nada!

Critérios e operadores do COUNTIF no Excel

Abaixo estão alguns dos operadores mais úteis para os critérios do COUNTIF, seja para contar com base em texto, números, células vazias e não vazias ou valores booleanos.

Valores de texto

Para encontrar correspondências com valores de texto, você tem muitas opções. Para uma correspondência exata, basta colocar a string entre aspas ou usar a referência da célula que contém a string. Para correspondências parciais, você pode usar os caracteres curinga abaixo.

• * Corresponde a 0 ou mais caracteres.
• ? Corresponde a um único caractere.
• ~ Se você precisar procurar os símbolos "*" ou "?", adicione o til antes do símbolo para escapá-lo, assim ele não é usado como curinga.

Por fim, a função não diferencia maiúsculas de minúsculas.

Números e datas

Se você quiser usar um valor numérico exato como critério, não precisa colocá-lo entre aspas. Mas, se quiser usar operadores de comparação, precisa colocar o critério entre aspas.

• <> diferente de
• = igual a
• >= maior ou igual a
• <= menor ou igual a
• > maior que
• < menor que

As datas funcionam da mesma forma, porque o Excel as armazena como números. Por exemplo, =COUNTIF(B2:B100,">="&DATE(2026,1,1)) conta as datas a partir de 1º de janeiro de 2026, inclusive.

Células vazias e não vazias

Use estes critérios para contar células vazias e não vazias.

• "" (duas aspas sem nada entre elas) conta as células vazias, como em =COUNTIF(A2:A13,"").
• "<>" conta as células que não estão vazias, como em =COUNTIF(A2:A13,"<>").

O curinga * do exemplo de curingas também ignora as células vazias, mas só conta células com texto, então deixa os números de fora.

Valores TRUE e FALSE (VERDADEIRO e FALSO)

Por fim, você também pode usar os valores booleanos TRUE e FALSE para contar células com base no resultado de uma fórmula ou para contar caixas de seleção marcadas ou desmarcadas. Por exemplo, =COUNTIF(E2:E20,TRUE) conta as caixas marcadas em E2:E20.

Exemplos de COUNTIF no Excel, passo a passo

Agora que você já revisou a sintaxe da função COUNTIF, é hora de ver alguns exemplos de como usá-la em diferentes situações.

Imagine que você tem uma tabela do Excel com dados de vendas, que inclui o nome do vendedor, a equipe, o produto e o valor da venda. Você precisa de várias contagens para o relatório de vendas, mas contar manualmente seria um pesadelo, já que a tabela tem quinhentas linhas.

Primeiro, selecione cada coluna e vá até a guia 'Fórmulas'. Clique em 'Criar a partir da Seleção' para nomear os intervalos e facilitar o trabalho com os dados.

As capturas de tela vêm de um Excel com configurações regionais europeias, por isso mostram ponto e vírgula entre os argumentos. Nas versões do Excel dos EUA e do Reino Unido, você digita vírgulas, como nos passos abaixo.

Contar células que contêm um texto exato

Siga os passos abaixo para contar as células que contêm um texto específico. Neste caso, vamos contar o número de vendas de 'Barret Smitten'.

1. Digite a função COUNTIF e selecione o intervalo de células que você quer contar. Neste caso, vou usar o intervalo nomeado 'sales_agent'.

2. Adicione uma vírgula e digite o critério entre aspas.

3. Adicione o parêntese de fechamento e pressione 'Enter' para ver o resultado.

A fórmula final é =COUNTIF(sales_agent,"Barret Smitten"), e retorna 21.

Contar células que contêm parte de um texto

Em vez de uma correspondência exata, você pode usar curingas para procurar parte do texto. Por exemplo, vamos contar o número de vendas da 'Northteam' procurando por 'North'.

1. Digite a função COUNTIF e selecione o intervalo de células que você quer contar.

2. Adicione uma vírgula e digite o critério entre aspas.

3. Adicione o parêntese de fechamento e pressione 'Enter' para ver o resultado.

A fórmula final é =COUNTIF(sales_team,"North*"), e retorna 189.

Contar valores maiores ou iguais a um número

Neste exemplo, vamos encontrar o número de vendas com valor maior ou igual a US$ 500.

1. Digite a função COUNTIF e selecione o intervalo de células que você quer contar.

2. Adicione uma vírgula e digite o critério entre aspas.

3. Adicione o parêntese de fechamento e pressione 'Enter' para ver o resultado.

A fórmula final é =COUNTIF(sales_amount,">=500"), e retorna 412.

Como usar COUNTIFS no Excel com vários critérios

No Microsoft Excel, você pode usar a função COUNTIFS para contar células com base em vários critérios, e cada critério pode ser aplicado a um ou mais intervalos.

Sintaxe do COUNTIFS

=COUNTIFS(criteria_range1, criterion1, criteria_range2, criterion2, ...)

Assim como o COUNTIF, a função COUNTIFS tem dois parâmetros obrigatórios. No entanto, você pode incluir parâmetros adicionais para testar vários intervalos com critérios diferentes. Lembre-se de que todos os intervalos precisam ter as mesmas dimensões, ou seja, o mesmo número de linhas e colunas.

• criteria_range1: o intervalo de células que você quer testar com o primeiro critério.
• criterion1: a condição ou teste que você quer aplicar ao primeiro intervalo.
• criteria_range2, criterion2, …: pares opcionais. Adicione quantos precisar. O COUNTIFS só conta uma linha quando ela atende a todos os critérios.

Os exemplos abaixo usam a mesma tabela de vendas dos exemplos de COUNTIF.

COUNTIFS com dois critérios em um mesmo intervalo

Por exemplo, vamos contar as vendas acima de US$ 600 e abaixo de US$ 1.000. O rótulo nas capturas de tela diz US$ 500, mas a fórmula e o resultado usam US$ 600.

1. Digite a função COUNTIFS e selecione o intervalo de células que você quer contar.

2. Adicione uma vírgula e digite o primeiro critério entre aspas.

3. Adicione uma vírgula e selecione o mesmo intervalo de antes. Adicione outra vírgula e digite o segundo critério entre aspas.

4. Adicione o parêntese de fechamento e pressione 'Enter' para ver o resultado.

A fórmula final é =COUNTIFS(sales_amount,">600",sales_amount,"<1000"), e retorna 103.

COUNTIFS com critérios em intervalos diferentes

Por fim, vamos contar o número de vendas de productA com valor maior ou igual a US$ 700.

1. Digite a função COUNTIFS e selecione o primeiro intervalo de células.

2. Adicione uma vírgula e digite o primeiro critério entre aspas.

3. Adicione uma vírgula e selecione o segundo intervalo de células. Adicione outra vírgula e digite o segundo critério entre aspas.

4. Adicione o parêntese de fechamento e pressione 'Enter' para ver o resultado.

A fórmula final é =COUNTIFS(product,"productA",sales_amount,">=700"), e retorna 80.

Erros comuns de COUNTIF e COUNTIFS e como corrigi-los

• O Excel diz que há um problema com a fórmula. Confira o separador entre os argumentos. O Excel usa vírgulas nos EUA e no Reino Unido, e ponto e vírgula nas regiões em que a vírgula é o separador decimal. Confira também se cada critério de texto tem aspas dos dois lados.
• Um operador retorna um erro. O operador fica dentro das aspas junto com o número, como em "<23". Para comparar com uma célula, junte o operador à referência da célula com um E comercial: "<"&B7.
• Um texto que parece igual não é contado. Um espaço no final já basta para impedir uma correspondência exata, então "Barret Smitten " e "Barret Smitten" contam como textos diferentes. Remova os espaços com TRIM (ARRUMAR) ou termine o critério com o curinga *.
• O COUNTIFS retorna #VALUE! (#VALOR!). Todos os intervalos de critérios precisam ter o mesmo tamanho. A2:A100 e B2:B90 não coincidem, então faça todos os intervalos começarem e terminarem nas mesmas linhas.
• #VALUE! quando o intervalo está em outra pasta de trabalho. COUNTIF e COUNTIFS não conseguem ler uma pasta de trabalho fechada. Abra o arquivo e a fórmula será recalculada.
• Resultados errados com textos longos. O COUNTIF não consegue encontrar correspondências com textos de mais de 255 caracteres. Divida o critério em dois e junte as metades com &, como em "first part"&"second part".

É assim que se usa COUNTIF e COUNTIFS no Excel

Esperamos que agora você entenda bem as várias formas de usar as funções COUNTIF e COUNTIFS do Excel e consiga colocá-las em prática com seus próprios dados. Boas contagens!

Para somar valores em vez de contá-los, veja como usar SUMIF no Excel. Para encontrar um valor em uma tabela, leia nosso guia de VLOOKUP no Excel, e para conhecer mais fórmulas úteis, veja as 10 principais funções do Excel.

Se você trabalha no Google Sheets, veja como usar COUNTIFS no Google Sheets e nosso post sobre a fórmula DCOUNT no Google Sheets.