Cómo usar SUMIF en Google Sheets

La función SUMIF de las Hojas de cálculo de Google te permite sumar valores de un intervalo en función de criterios específicos. Tanto si se trata de datos financieros, listas de inventario o cualquier otro conjunto de datos, puede realizar cálculos de forma eficiente.

Esta guía le guiará a través de la sintaxis de la función SUMIF, proporcionará casos prácticos de uso e introducirá la función SUMIFS para manejar múltiples criterios.

Sintaxis de SUMIF y SUMIFS en Google Sheets

Repasemos la sintaxis de SUMIF (SUMAR.SI) y SUMIFS (SUMAR.SI.CONJUNTO) antes de usarlas.

Sintaxis de SUMIF

La función SUMIF de Google Sheets tiene dos parámetros obligatorios y uno opcional.

=SUMIF(range, criterion,[sum_range])

range: el rango de celdas que quieres evaluar con el criterio.
criterion: la prueba o condición que quieres aplicar al rango.
sum_range: el rango que quieres sumar, si es distinto del rango usado como primer parámetro.

Sintaxis de SUMIFS: el rango de suma va primero

La función SUMIFS de Google Sheets tiene tres parámetros obligatorios. Sin embargo, SUMIFS te permite añadir parámetros adicionales para evaluar varios rangos con criterios distintos.

=SUMIFS(suma_rango, criterio_rango1, criterio1, [criterio_rango2, criterio2, ...])

Fíjate en el orden: en SUMIFS el rango de suma va primero, mientras que en SUMIF va al final y es opcional. sum_range, el primer rango y el primer criterio son argumentos obligatorios.

sum_range: el rango que quieres sumar.
criteria_range1: el rango de celdas que quieres evaluar con el primer criterio.
criterion1: la prueba o condición que quieres aplicar al primer rango.

Los rangos y criterios adicionales son opcionales, pero puedes añadir tantos como quieras. Eso sí, los rangos siguientes deben tener las mismas dimensiones que el primero: todos los rangos deben tener el mismo número de filas y columnas.

criteria_range2*: el segundo rango de celdas que quieres evaluar con el segundo criterio.
criterion2*: la prueba o condición que quieres aplicar al segundo rango.

Encontrarás más ejemplos en nuestra guía de SUMIFS con varios criterios.

Cómo escribir los criterios de SUMIF y SUMIFS

Hay muchos operadores útiles para definir los criterios o condiciones de las funciones SUMIF y SUMIFS. Por ejemplo, estas dos fórmulas suman los valores situados junto a celdas no vacías y junto a celdas vacías, respectivamente.

=SUMIF(range, "<>", sum_range)
=SUMIF(range, "", sum_range)

Números y operadores de comparación

Con valores numéricos exactos no necesitas comillas. Pero si usas operadores de comparación, tendrás que poner la condición o el criterio entre comillas.

<> distinto de
= igual a
>= mayor o igual que
<= menor o igual que
> mayor que
< menor que

Texto y comodines

Con los valores de texto también tienes muchas opciones. Además de buscar un texto exacto entre comillas, puedes usar cualquiera de estos comodines para coincidencias parciales.

* Coincide con 0 o más caracteres.
? Coincide con un solo carácter.
~ Si necesitas buscar los símbolos "*" o "?", añade la tilde (~) antes del símbolo para escaparlo y que no se use como comodín.

Cómo escribir una fórmula SUMIF paso a paso

Ahora que has repasado la sintaxis de la función, es hora de ver algunos ejemplos de cómo usar SUMIF en distintas situaciones.

Imagina que tienes una tabla de ventas con la fecha, el nombre del agente de ventas, su equipo, el producto y el importe de la venta. Necesitas varios totales para tu informe de ventas y sumarlos a mano te llevaría una eternidad, porque la tabla tiene quinientas filas.

SUMIF en Google Sheets — tabla de ventas con las columnas date, sales_agent, product, sales_team y sales_amount

SUMIF con un criterio de texto

En este ejemplo, quiero sumar los importes de venta de "productA".

1. En una celda vacía, escribe la fórmula SUMIF.

Fórmula SUMIF en Google Sheets — =SUMIF( escrito en la celda G2 bajo sales total productA

2. Selecciona el rango al que quieres aplicar el criterio. En este caso, la columna de los productos.

Fórmula SUMIF en Google Sheets — columna de producto C:C seleccionada como rango

3. Añade el criterio que quieres aplicar al rango seleccionado. En este ejemplo, quiero una coincidencia exacta con "productA".

Fórmula SUMIF en Google Sheets — productA escrito como criterio

4. A continuación, selecciona el rango con los valores que quieres sumar, si es distinto del primer rango seleccionado. En este caso lo es, porque quiero sumar los valores de la columna del importe de ventas.

Fórmula SUMIF en Google Sheets — columna sales_amount E:E seleccionada como rango de suma

5. Y listo. =SUMIF(C:C,"productA",E:E) devuelve $119,308.93, el total de ventas de productA.

Resultado de SUMIF en Google Sheets — total de $119,308.93 para productA en la celda G2

SUMIF con un rango de fechas

Imagina que necesitas sumar valores según la fecha de venta en lugar del producto o de otro valor de texto. En este ejemplo, calcularé el importe total de las ventas realizadas el 1 de febrero de 2022 o después.

1. Escribe la función SUMIF en una celda vacía.

SUMIF con rango de fechas en Google Sheets — =SUMIF( escrito en la celda G5 bajo Sales after Feb.1st

2. Selecciona el rango al que quieres aplicar el criterio. En este ejemplo, seleccionaré la columna de las fechas.

SUMIF con rango de fechas en Google Sheets — columna de fecha A:A seleccionada como rango

3. El criterio debe comprobar si la fecha es igual o posterior al 1 de febrero de 2022.

SUMIF con rango de fechas en Google Sheets — igual o posterior a 2/1/22 escrito como criterio

4. A continuación, selecciona el rango con los valores que se van a sumar. Abajo he elegido la columna de los importes de venta.

SUMIF con rango de fechas en Google Sheets — columna sales_amount E:E seleccionada como rango de suma

5. Y listo. El importe total de las ventas realizadas el 1 de febrero de 2022 o después es de $332,194.88. La fórmula completa es =SUMIF(A:A,">=2/1/22",E:E).

Resultado de SUMIF con rango de fechas en Google Sheets — $332,194.88 en ventas después del 1 de febrero en la celda G5

Más ejemplos de SUMIF: mayor que 0, texto parcial y distinto de

Cada una de estas fórmulas usa una sola condición. Sustituye los rangos por los tuyos.

SUMIF mayor que 0

El SUMIF puede sumar valores mayores que cero.

Esto resulta especialmente útil para los datos financieros, en los que es posible que desee excluir los saldos negativos o los valores cero de los totales.

En el ejemplo siguiente la función suma todos los valores de A1:A10 que son mayores que 0.

=SUMIF(A1:A10, ">0")

SUMIF con texto parcial

El SUMIF también puede utilizarse para sumar valores basándose en criterios de texto. Incluso puede incluir comodines para considerar coincidencias parciales.

Esto resulta útil cuando se trabaja con conjuntos de datos que incluyen entradas de texto, como nombres de productos o categorías, y se desea sumar valores numéricos relacionados.

El siguiente ejemplo suma los valores de B1:B10 cuyas celdas correspondientes de A1:A10 contienen la cadena "text".

=SUMIF(A1:A10, "*text*", B1:B10)

SUMIF no es igual a

A veces, puede que necesite excluir valores específicos de su suma.

El SUMIF puede sumar valores que no sean iguales a un criterio, lo que es estupendo para filtrar datos no deseados.

El ejemplo siguiente suma los valores de A1:A10 cuando las celdas no son iguales a 5.

=SUMIF(A1:A10, "5")

SUMIF vs SUMIFS: cuándo necesitas más de una condición

SUMIF comprueba una condición. Cuando un total depende de dos o más, como un producto vendido después de cierta fecha, usa SUMIFS.

Las dos funciones reciben los argumentos en un orden distinto, y ahí es donde se cometen la mayoría de los errores:

=SUMIF(range, criterion, [sum_range]): el rango que se suma va al final y puedes omitirlo.
=SUMIFS(sum_range, criteria_range1, criterion1, …): el rango que se suma va primero y no puedes omitirlo.

SUMIFS solo suma una fila cuando se cumplen todas las condiciones. Para sumar las filas que cumplen una condición u otra, suma dos fórmulas SUMIF, por ejemplo =SUMIF(C:C,"productA",E:E)+SUMIF(C:C,"productC",E:E).

Para ver más casos, consulta nuestra guía sobre SUMIFS con varios criterios.

Ejemplos de SUMIFS con varios criterios

La función SUMIFS te permite sumar valores según varios criterios, que se pueden aplicar a varios rangos. Para simplificar, los siguientes ejemplos usan el mismo conjunto de datos que el de SUMIF.

SUMIFS con criterios en columnas distintas

En este ejemplo, quiero sumar los importes de todas las ventas de productA realizadas el 1 de febrero de 2022 o después.

1. En una celda vacía, escribe la fórmula SUMIFS.

SUMIFS en Google Sheets — =SUMIFS( escrito en la celda G2 con sum_range resaltado en el cuadro de ayuda

2. Selecciona el rango que contiene los valores que quieres sumar.

SUMIFS en Google Sheets — columna sales_amount E:E seleccionada como rango de suma

3. Selecciona el primer rango al que quieres aplicar el primer criterio. En este caso es distinto del rango de suma, porque quiero comprobar la columna de los productos.

SUMIFS en Google Sheets — columna de producto C:C seleccionada como primer rango de criterios

4. Añade el criterio que quieres aplicar al primer rango. En este ejemplo, quiero una coincidencia exacta con "productA".

SUMIFS en Google Sheets — productA escrito como primer criterio

5. A continuación, selecciona el segundo rango. Es el rango al que quieres aplicar el segundo criterio. Abajo he seleccionado la columna de las fechas.

SUMIFS en Google Sheets — columna de fecha A:A seleccionada como segundo rango de criterios

6. Añade el segundo criterio, que se aplicará al segundo rango. En este ejemplo, he indicado que la fecha debe ser el 1 de febrero de 2022 o posterior.

SUMIFS en Google Sheets — igual o posterior a 2/1/22 escrito como segundo criterio

7. Y listo. Las ventas de productA realizadas en la fecha seleccionada o después suman $70,811.22. La fórmula completa es =SUMIFS(E:E,C:C,"productA",A:A,">=2/1/22").

Resultado de SUMIFS en Google Sheets — $70,811.22 en ventas de productA después del 1 de febrero

SUMIFS con dos criterios en la misma columna

SUMIFS también se puede usar aplicando varios criterios a un solo rango. Veamos cómo calcular el importe total de las ventas con un valor entre $500 y $1000.

1. Escribe la fórmula SUMIFS en una celda vacía.

SUMIFS con dos criterios en una columna — =SUMIFS( escrito bajo total sum of sales between $500 and $1000

2. Selecciona el rango de celdas que contiene los valores que quieres sumar.

SUMIFS con dos criterios en una columna — columna sales_amount E:E seleccionada como rango de suma

3. Selecciona el rango al que quieres aplicar el primer criterio. En este caso, es el mismo que el rango de suma.

SUMIFS con dos criterios en una columna — E:E seleccionado de nuevo como primer rango de criterios

4. Añade el primer criterio. En este ejemplo, quiero comprobar que los valores sean mayores o iguales que $500.

SUMIFS con dos criterios en una columna — al menos 500 escrito como primer criterio

5. Selecciona el rango que quieres comprobar con el segundo criterio. En este caso, es el mismo que el rango de suma y el primer rango.

SUMIFS con dos criterios en una columna — E:E seleccionado como segundo rango de criterios

6. Añade el segundo criterio. Abajo he indicado que los valores deben ser menores o iguales que $1000.

SUMIFS con dos criterios en una columna — como máximo 1000 escrito como segundo criterio

7. Y listo. Tienes el total de los valores entre $500 y $1000: $98,510.33. La fórmula completa es =SUMIFS(E:E,E:E,">=500",E:E,"<=1000").

Resultado de SUMIFS en Google Sheets — $98,510.33 en ventas entre $500 y $1000

Errores habituales de SUMIF y SUMIFS

Cuando una fórmula devuelve un error o un total que parece incorrecto, revisa primero esto:

Si conviertes un SUMIF en un SUMIFS, mueve el rango de suma al principio. Si lo dejas al final, devuelve un error o un total incorrecto.
En SUMIFS, cada rango de criterios necesita el mismo número de filas y columnas que el rango de suma. Si alguno es más corto, obtienes #VALUE!.
Los operadores van entre comillas: escribe ">5", no >5. Para comparar con una celda, une el operador a ella, como en ">="&B1.
Las fechas escritas en el criterio, como ">=2/1/22", se interpretan según la configuración regional de la hoja de cálculo. ">="&DATE(2022,2,1) funciona con cualquier configuración regional.
SUMIF y SUMIFS ignoran los números almacenados como texto, así que el total sale más bajo. Vuelve a introducirlos como números o conviértelos con VALUE en una columna auxiliar.

Conclusión

SUMIF y SUMIFS son funciones versátiles y fáciles de usar. Puedes sumar valores según uno o varios criterios, y esos criterios se pueden aplicar a uno o varios rangos. Ya conoces la sintaxis de ambas funciones y cómo crear criterios con operadores lógicos y de comparación sobre valores numéricos y de texto. También tienes ejemplos de varios escenarios con ambas funciones, con instrucciones paso a paso.

Para saber más sobre las funciones relacionadas COUNTIF y COUNTIFS, consulta nuestra guía sobre COUNTIF y COUNTIFS en Google Sheets: fórmula y ejemplos.

Para contar las celdas que cumplen la condición en lugar de sumarlas, descubre cómo usar COUNTIF para valores mayores que 0. Para fórmulas que devuelven un valor según una condición, lee nuestra guía sobre funciones IF en Google Sheets. Para descubrir más formas de explorar y resumir tus números, consulta nuestra guía de análisis de datos en Google Sheets.

Si los números que sumas están repartidos en varias hojas de cálculo, Sheetgo puede reunirlos en un solo lugar y mantenerlos actualizados automáticamente, para que tus totales de SUMIF estén siempre al día y tus datos listos para el análisis con IA.